Manual Structure Calculation Using CYANA

Manual structure calculation with CYANA 2.1

Manual structure calculation is performed similar to the automated calculation.

1. Create a new working subdirectory (structure/cyana21/calc3)
2. Copy init.cya, XXXX.seq, XXXX.prot into this directiory.
3. Export the latest peaklists, like n-cons, ali-cons and aro-cons.
4. Copy the latest stereofound.cya from the latest GridSearch run.
5. (Optional) Copy the talos.aco file
6. Download the CALC.cya file (see below). Modify peaklist names, calibration parameters and tolerances.
7. Run calculation with CYANA 2.1 on a workstation or U2 cluster

CALC.cya

peaks      := n_cons,ali_cons,aro_cons           # names of peak lists
prot       := $name                  # names of proton lists
tolerance  := 0.05,0.02,0.4          # chemical shift tolerances
                                     # order: 1H(a), 1H(b), 13C/15N(b), 13C/15N(a)
if (master) then
  # ---- check consistency of peak and chemical shift lists----
  peakcheck peaks=$peaks prot=$prot
  # ---- calibration ----
  read prot $prot
  read peaks n_cons
  peaks set volume=abs(volume)
  caliba bb=2.0E+06 sc=2.0E+05 methyl=4.0E+04
  write upl n
  read peaks ali_cons
  peaks set volume=abs(volume)
  caliba bb=2.5E+06 sc=4.3E+05 methyl=2.0E+05
  write upl ali
  read peaks aro_cons
  peaks set volume=abs(volume)
  caliba bb=1.7E+06 sc=2.4E+05 methyl=6.0E+04
 
  write upl $name-in.upl
  stereofound
  distance modify
  write upl $name.upl
end if
synchronize
 
# ---- structure calculation ----
expand=0
read seq $name.seq                             # re-read sequence to initialize
read upl $name.upl                             # read upper distance limits
#read aco talos.aco                            # read angle constraints
seed=5671                                      # random number generator seed
calc_all structures=100 command=anneal steps=10000    # calculate 100 conformers
flip                                           # align side chains for lower RMSD
overview $name.ovw structures=20 pdb    # write overview file and coordinates
#overview $name.ovw structures=20 significant=1 pdb

Here expand=0 is needed to correctly interpret UPLs created with CALIBA.

Macro flip.cya can be used to flip the side chains Glu, Asp, Phe and Tyr to reduce RMSD in the final calculation.

Overview by default will report only violation in at least structures/3 conformers, and in this particular case these are six. To have all violations reported add significant=1.

Macro peakcheck verifies AtomList and peaklists for consistency and is very useful when manually assigned peaks are used.

It is important to set peak volumes to their absolute values before calling caliba for calibration.

-- Main.AlexEletski - 10 Jul 2007